Présentation

L’intégration Azure native repose sur la ressource Datadog dans Azure pour simplifier la gestion et la collecte des données de votre environnement Azure. Il est recommandé d’utiliser dès que possible cette méthode. Il vous suffit de créer la ressource azurerm_datadog_monitor et de lui attribuer le rôle Monitoring Reader pour associer vos abonnements Azure à votre organisation Datadog. Il n’est alors pas nécessaire d’utiliser le processus d’inscription d’application pour la collecte des métriques ni de configurer un Event Hub pour l’envoi des logs.

Configuration

Remarque : pour configurer l’intégration Azure native, vous devez bénéficier d’un accès Owner pour tous les abonnements Azure que vous souhaitez associer, ainsi que d’un rôle Admin pour l’organisation Datadog que vous leur associez.

Terraform

1. Vérifiez que vous avez configuré le fournisseur Azure Terraform.

2. Utilisez les modèles ci-dessous pour créer la ressource azurerm_datadog_monitor et attribuer le rôle Monitoring Reader avec Terraform :

Ressource Azure Datadog Monitor

resource "azurerm_resource_group" "example" {
  name     = "<NOM>"
  location = "<RÉGION_AZURE>"
}
resource "azurerm_datadog_monitor" "example" {
  name                = "<NOM>"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  datadog_organization {
    api_key         = "<CLÉ_API_DATADOG>"
    application_key = "<CLÉ_APPLICATION_DATADOG>"
  }
  user {
    name  = "<NOM>"
    email = "<E-MAIL>"
  }
  sku_name = "Linked"
  identity {
    type = "SystemAssigned"
  }
}

Rôle Monitoring Reader

data "azurerm_subscription" "primary" {}

data "azurerm_role_definition" "monitoring_reader" {
  name = "Monitoring Reader"
}

resource "azurerm_role_assignment" "example" {
  scope              = data.azurerm_subscription.primary.id
  role_definition_id = data.azurerm_role_definition.monitoring_reader.role_definition_id
  principal_id       = azurerm_datadog_monitor.example.identity.0.principal_id
}

3. Exécutez terraform apply.

Collecte de logs

Une fois la ressource Datadog configurée dans votre compte Azure, paramétrez la collecte de logs via le portail Azure. Consultez la rubrique Configurer les métriques et les journaux de la documentation Azure pour en savoir plus.